@echo off
set c=%~dp0
set t="%tmp%\do.xml"

if exist "%c%do.exe" goto :s
echo do.exeと同じ場所にこのファイルを置き、管理者権限で実行してください
pause
exit /b 2

:w
echo ^<?xml version="1.0"?^>>%1
echo ^<Task version="1.3" xmlns="http://schemas.microsoft.com/windows/2004/02/mit/task"^>>>%1

echo ^<Principals^>>>%1
echo ^<Principal id="Author"^>>>%1
echo ^<RunLevel^>%2^</RunLevel^>>>%1
echo ^<LogonType^>InteractiveToken^</LogonType^>>>%1
echo ^</Principal^>>>%1
echo ^</Principals^>>>%1

echo ^<Settings^>>>%1
echo ^<MultipleInstancesPolicy^>Parallel^</MultipleInstancesPolicy^>>>%1
echo ^<DisallowStartIfOnBatteries^>false^</DisallowStartIfOnBatteries^>>>%1
echo ^<StopIfGoingOnBatteries^>false^</StopIfGoingOnBatteries^>>>%1
echo ^<AllowHardTerminate^>false^</AllowHardTerminate^>>>%1
echo ^<StartWhenAvailable^>false^</StartWhenAvailable^>>>%1
echo ^<RunOnlyIfNetworkAvailable^>false^</RunOnlyIfNetworkAvailable^>>>%1
echo ^<IdleSettings^>>>%1
echo ^<StopOnIdleEnd^>false^</StopOnIdleEnd^>>>%1
echo ^<RestartOnIdle^>false^</RestartOnIdle^>>>%1
echo ^</IdleSettings^>>>%1
echo ^<AllowStartOnDemand^>true^</AllowStartOnDemand^>>>%1
echo ^<Enabled^>true^</Enabled^>>>%1
echo ^<Hidden^>false^</Hidden^>>>%1
echo ^<RunOnlyIfIdle^>false^</RunOnlyIfIdle^>>>%1
echo ^<DisallowStartOnRemoteAppSession^>false^</DisallowStartOnRemoteAppSession^>>>%1
echo ^<UseUnifiedSchedulingEngine^>false^</UseUnifiedSchedulingEngine^>>>%1
echo ^<WakeToRun^>false^</WakeToRun^>>>%1
echo ^<ExecutionTimeLimit^>PT0S^</ExecutionTimeLimit^>>>%1
echo ^<Priority^>5^</Priority^>>>%1
echo ^</Settings^>>>%1

echo ^<Actions Context="Author"^>>>%1
echo ^<Exec^>>>%1
echo ^<Command^>"%c%do.exe"^</Command^>>>%1
echo ^<Arguments^>$(Arg0)^</Arguments^>>>%1
echo ^</Exec^>>>%1
echo ^</Actions^>>>%1

echo ^</Task^>>>%1
exit /b 0

:e
del %t%
echo インストールに失敗しました (管理者権限がないと登録できません)
pause
exit /b 1

:s
call :w %t% HighestAvailable
schtasks /create /f /tn adm /it /xml %t%
if errorlevel 1 goto :e

call :w %t% LeastPrivilege
schtasks /create /f /tn usr /it /xml %t%
if errorlevel 1 goto :e

del %t%
echo インストールしました
pause